DIY IoT สำหรับบ้านเลี้ยงแมว: ทำฝาอาหารล็อกได้ด้วย Servo บน ESP8266

#include <Servo.h>
#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <WiFiUdp.h>

ESP8266WiFiMulti wifiMulti;
WiFiUDP UDP;

IPAddress timeServerIP;
const char* NTPServerName = "time.nist.gov";
const int NTP_PACKET_SIZE = 48;
byte NTPBuffer[NTP_PACKET_SIZE];

Servo myservo;
int pos = 0;

void setup() {
  myservo.attach(5);  // D1

  Serial.println("opening the lid");
  for (pos = 95; pos >= 0; pos -= 1) {
    myservo.write(pos);
    delay(15);
  }
    
  Serial.begin(115200);
  delay(10);
  Serial.println("\r\n");

  startWiFi();
  startUDP();

  if(!WiFi.hostByName(NTPServerName, timeServerIP)) {
    Serial.println("DNS lookup failed. Rebooting.");
    Serial.flush();
    ESP.reset();
  }
  sendNTPpacket(timeServerIP);  
}

unsigned long intervalNTP = 60000;
unsigned long prevNTP = 0;
unsigned long lastNTPResponse = millis();
uint32_t timeUNIX = 0;
unsigned long prevActualTime = 0;

void loop() {
  unsigned long currentMillis = millis();

  if (currentMillis - prevNTP > intervalNTP) {
    prevNTP = currentMillis;
    sendNTPpacket(timeServerIP);
  }

  uint32_t time = getTime();
  if (time) {
    timeUNIX = time;
    lastNTPResponse = currentMillis;
  } else if ((currentMillis - lastNTPResponse) > 3600000) {
    ESP.reset();
  }

  uint32_t actualTime = timeUNIX + (currentMillis - lastNTPResponse)/1000;
  uint32_t easternTime = timeUNIX - 18000 + (currentMillis - lastNTPResponse)/1000;
  
  if (actualTime != prevActualTime && timeUNIX != 0) {
    prevActualTime = actualTime;
  } 

  // 7:30am Open
  if(getHours(easternTime) == 7 && getMinutes(easternTime) == 30 && getSeconds(easternTime) == 0){
    for (pos = 95; pos >= 0; pos -= 1) {
      myservo.write(pos);
      delay(15);
    }    
  }

  // Midnight Close
  if(getHours(easternTime) == 0 && getMinutes(easternTime) == 0 && getSeconds(easternTime) == 0){
    for (pos = 0; pos <= 95; pos += 1) {
      myservo.write(pos);
      delay(15);
    }    
  }   
}

void startWiFi() {
  // แก้ไข SSID และ Password ตรงนี้
  wifiMulti.addAP("ssid_from_AP_1", "your_password_for_AP_1");   

  Serial.println("Connecting");
  while (wifiMulti.run() != WL_CONNECTED) {
    delay(250);
    Serial.print('.');
  }
}

void startUDP() {
  UDP.begin(123);
}

uint32_t getTime() {
  if (UDP.parsePacket() == 0) { return 0; }
  UDP.read(NTPBuffer, NTP_PACKET_SIZE);
  uint32_t NTPTime = (NTPBuffer[40] << 24) | (NTPBuffer[41] << 16) | (NTPBuffer[42] << 8) | NTPBuffer[43];
  const uint32_t seventyYears = 2208988800UL;
  uint32_t UNIXTime = NTPTime - seventyYears;
  return UNIXTime;
}

void sendNTPpacket(IPAddress& address) {
  memset(NTPBuffer, 0, NTP_PACKET_SIZE);
  NTPBuffer[0] = 0b11100011;
  UDP.beginPacket(address, 123);
  UDP.write(NTPBuffer, NTP_PACKET_SIZE);
  UDP.endPacket();
}

inline int getSeconds(uint32_t UNIXTime) { return UNIXTime % 60; }
inline int getMinutes(uint32_t UNIXTime) { return UNIXTime / 60 % 60; }
inline int getHours(uint32_t UNIXTime) { return UNIXTime / 3600 % 24; }
    

สนใจอุปกรณ์ IoT หรือพูดคุยแลกเปลี่ยนไอเดีย?

คำเตือน: เนื้อหานี้เป็นการสรุปและเรียบเรียงจากบทความต้นฉบับภาษาอังกฤษ ข้อมูลฉบับภาษาไทยอาจมีความคลาดเคลื่อนบางประการจากการตีความหรือย่อเนื้อหา

อ้างอิง: บทความนี้แปลและเรียบเรียงโดย Globalbyteshop Blog
ต้นฉบับโดย Becky Stern จาก Instructables: Cat Food Bowl Access Control (ESP8266 + Servo Motor + 3D Printing)