// [Google Apps Script] สคริปต์รับค่า HTTP GET แล้วประทับสถิติลง Google Sheets
function doGet(e) {
  var sheet = SpreadsheetApp
      .openById("YOUR_SHEET_ID") // ใส่ Sheet ID ของคุณ
      .getSheetByName("Attendance");

  sheet.appendRow([
    e.parameter.uid,
    e.parameter.name,
    e.parameter.status,
    new Date() // ประทับเวลาอัตโนมัติ
  ]);

  return ContentService.createTextOutput("SUCCESS");
}

// [Arduino C++] โค้ดควบคุมระบบเช็กชื่อ Apple Wallet & RFID ลง Google Sheets
#include <WiFiS3.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const char* ssid = "YOUR_WIFI_SSID";
const char* password = "YOUR_WIFI_PASSWORD";

const char* host = "script.google.com";
const int httpsPort = 443;
String GScriptId = "YOUR_APPS_SCRIPT_DEPLOYMENT_ID";

WiFiSSLClient client;

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

const String TEACHER_PASS = "Reyax|RYRR30DTest|88880000";

struct Student {
  String uid;
  String name;
};

Student students[] = {
  {"D784D500", "Student 1"},
  {"7EB6F300", "Student 2"},
  {"23370EAA", "Student 3"}
};
const int numStudents = 3;

enum SystemState { WAITING_FOR_TEACHER, SETTLING, IN_SESSION };
SystemState currentState = WAITING_FOR_TEACHER;

unsigned long lastConfirmedApple = 0;
unsigned long lastCardTime = 0;
String lastCardUID = "";

const unsigned long APPLE_DEBOUNCE = 6000;
const unsigned long CARD_DEBOUNCE = 3000;

unsigned long settleStartTime = 0;
const unsigned long SETTLE_TIME = 3500;

bool hasPendingCard = false;
String pendingUID = "";
unsigned long pendingCardTime = 0;
const unsigned long HOLD_WINDOW = 1300;

void setup() {
  Serial.begin(115200);
  Serial1.begin(115200);

  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  showMessage("Welcome To\nSchool");
  delay(2000);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) { delay(500); }
  showMessage("WiFi\nConnected!");
  delay(1500);

  // ตั้งค่า REYAX RYRR30D โหมด Apple Wallet & RFID
  Serial1.print("AT+APPLE=1,60e9798a4d98f0fd86ed5ef0eb459ffb72154ad47694bbc89f9b352ba3ad739d,7dea8e42245bc14db7c2e359218fca2f4566a68eac704c29ec3286fa063e2cea\r\n");
  delay(200);
  Serial1.print("AT+MODE=2\r\n");
  delay(200);

  showMessage("Waiting For\nTeacher");
}

void loop() {
  unsigned long now = millis();

  if (Serial1.available()) {
    String data = Serial1.readStringUntil('\n');
    data.trim();

    if (data.startsWith("+APPLE=")) {
      String payload = data.substring(data.indexOf(',') + 1);
      if (payload == TEACHER_PASS && (now - lastConfirmedApple > APPLE_DEBOUNCE)) {
        lastConfirmedApple = now;
        if (currentState == WAITING_FOR_TEACHER) {
          currentState = SETTLING;
          settleStartTime = now;
          showMessage("Remove\nPhone");
        } else {
          currentState = WAITING_FOR_TEACHER;
          showMessage("Waiting For\nTeacher");
        }
      }
    } else if (data.startsWith("+ISO14443A=")) {
      if (currentState == IN_SESSION) {
        String uid = data.substring(data.indexOf('=') + 1);
        if (!(uid == lastCardUID && (now - lastCardTime < CARD_DEBOUNCE))) {
          pendingUID = uid;
          pendingCardTime = now;
          hasPendingCard = true;
        }
      }
    }
  }

  if (currentState == SETTLING && (now - settleStartTime >= SETTLE_TIME)) {
    currentState = IN_SESSION;
    showMessage("Tap Student\nCards Now");
  }

  if (hasPendingCard && (now - pendingCardTime >= HOLD_WINDOW)) {
    hasPendingCard = false;
    lastCardUID = pendingUID;
    lastCardTime = now;

    String studentName = getStudentName(pendingUID);
    if (studentName != "") {
      sendToGoogleSheet(pendingUID, studentName, "Present");
    } else {
      sendToGoogleSheet(pendingUID, "Unknown", "Invalid");
    }
    showMessage("Tap Student\nCards Now");
  }
}

String getStudentName(String uid) {
  for (int i = 0; i < numStudents; i++) {
    if (uid == students[i].uid) return students[i].name;
  }
  return "";
}

void sendToGoogleSheet(String uid, String name, String status) {
  if (WiFi.status() != WL_CONNECTED) return;
  if (client.connect(host, httpsPort)) {
    String url = "/macros/s/" + GScriptId + "/exec?uid=" + uid + "&name=" + name + "&status=" + status;
    client.println("GET " + url + " HTTP/1.1");
    client.println("Host: " + String(host));
    client.println("Connection: close");
    client.println();
    client.stop();
  }
}

void showMessage(String msg) {
  display.clearDisplay();
  display.setTextSize(2);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 10);
  display.println(msg);
  display.display();
}